// MyClass contains the property "prop1"
var myClassInstance: MyClass = new MyClass();
myClassInstance.prop1 = "The value";

var myProxy: ObjectProxy = new ObjectProxy(myClassInstance);

trace(myProxy.prop1); // Outputs "The value"

trace(myProxy.prop2); // ERROR! "prop2" doesn't exist in MyClass

var myProxy: ObjectProxy = new ObjectProxy();
myProxy.prop2 = "The property value";

trace(myProxy.prop2); // Outputs "The property value"

package com.devahead.utils
{
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.events.IEventDispatcher;
	import flash.utils.Proxy;
	import flash.utils.describeType;
	import flash.utils.flash_proxy;
	import flash.utils.getQualifiedClassName;

	import mx.events.PropertyChangeEvent;
	import mx.utils.ObjectProxy;

	[Bindable("propertyChange")]
	public dynamic class DynaObjectProxy extends Proxy implements IEventDispatcher
	{
		/**
		 * EventDispatcher used by the proxy to dispatch events.
		 */
		protected var _dispatcher: EventDispatcher;

		/**
		 * Object managed by the proxy.
		 */
		protected var _managedObj: Object = null;

		/**
		 * ObjectProxy used to managed the _managedObj.
		 */
		protected var _managedObjProxy: ObjectProxy = null;

		/**
		 * ObjectProxy used to allow the dynamic creation of
		 * new bindable properties.
		 */
		protected var _dynamicObjProxy: ObjectProxy = null;

		/**
		 * List of the properties belonging to the proxy. It contains, in
		 * alphabetical order, the list of all the properties beloging to
		 * the _managedObj plus those created dynamically on the _dynamicObjProxy.
		 */
		protected var _propertyList: Array = null;

		/**
		 * Constructor.
		 *
		 * @param managedObj
		 *         Object managed by the proxy.
		 */
		public function DynaObjectProxy(managedObj: Object = null)
		{
			super();

			_managedObj = managedObj;

			_propertyList = new Array();

			// Create the ObjectProxy to manage the managedObj and the one to manage
			// the dynamically created properties.
			_managedObjProxy = (managedObj != null ?
				new ObjectProxy(managedObj) :
				new ObjectProxy());

			_dynamicObjProxy = new ObjectProxy();

			// Create the events dispatcher and attach the appropriate listeners
			// to both the ObjectProxy.
			_dispatcher = new EventDispatcher(this);
			_managedObjProxy.addEventListener(PropertyChangeEvent.PROPERTY_CHANGE, onPropertyChangeEvent);
			_dynamicObjProxy.addEventListener(PropertyChangeEvent.PROPERTY_CHANGE, onPropertyChangeEvent);
		}

		/**
		 * Returns all the properties beloging to an object.
		 *
		 * @param obj
		 *         Object.
		 * @return All the object's properties.
		 */
		public static function getObjectProperties(obj: Object): Array
		{
			var result: Array = new Array();

			var objClassInfo: XML = describeType(obj);

			for each (var v: XML in objClassInfo..accessor)
			{
				result.push(String(v.@name));
			}

			return result;
		}

		/**
		 * Returns the original instance of the object managed internally
		 * by the proxy.
		 */
		public function get managedObj(): Object
		{
			return _managedObj;
		}

		/**
		 * Update the list of all the properties available in the proxy (those
		 * visible from outside the proxy by its users).
		 * The list contains, in alphabetical order, the set of the properties
		 * in the managedObj and those in the dynamicObj.
		 */
		protected function updatePropertyList(): void
		{
			var newPropertyList: Array = new Array();

			if (_managedObj != null)
			{
				if (getQualifiedClassName(_managedObj) == "Object")
				{
					// This is an Object so I can get all of its properties
					// through a cycle.
					for (var managedPropName: String in _managedObj)
					{
						newPropertyList.push(managedPropName);
					}
				}
				else
				{
					// This is likely to be a typed object so I get all its properties
					// through the getObjectProperties function.
					newPropertyList = getObjectProperties(_managedObj);
				}
			}

			// Add to the list also the properties created dynamically in the
			// dynamicObj.
			for (var dynamicPropName: String in _dynamicObjProxy)
			{
				newPropertyList.push(dynamicPropName);
			}

			// Update the _propertyList and sort it in alphabetical order.
			_propertyList = newPropertyList;
			_propertyList.sort();
		}

		/**
		 * Handler for the properties changes in the managedObj and the dynamicObj.
		 * This function dispatches again the PropertyChangeEvent as if it was
		 * generated by this proxy instead of the internal ObjectProxy used for
		 * managedObj and dynamicObj.
		 *
		 * @param event
		 *         Event.
		 */
		protected function onPropertyChangeEvent(event: PropertyChangeEvent): void
		{
			var newEvent: PropertyChangeEvent = new PropertyChangeEvent(event.type,
				event.bubbles, event.cancelable, event.kind, event.property,
				event.oldValue, event.newValue, this);

			dispatchEvent(newEvent);
		}

		// *** Implementation of Proxy methods ***

		override flash_proxy function getProperty(name: *): *
		{
			// If the property is in the managedObj then I return its value,
			// otherwise I use property's value from the dynamicObj.
			return (_managedObjProxy.hasOwnProperty(name) ?
				_managedObjProxy[name] :
				_dynamicObjProxy[name]);
		}

		override flash_proxy function callProperty(name: *, ... rest): *
		{
			// If the function is in the managedObj then I call it,
			// otherwise I call the function in the dynamicObj.
			return (_managedObjProxy.hasOwnProperty(name) ?
				_managedObjProxy[name].apply(_managedObjProxy, rest) :
				_dynamicObjProxy[name].apply(_dynamicObjProxy, rest));
		}

		override flash_proxy function deleteProperty(name: *): Boolean
		{
			// I cannot delete a property from the managedObj, so I delete it directly
			// from the dynamicObj.
			return (_dynamicObjProxy.hasOwnProperty(name) ?
				delete _dynamicObjProxy[name] : false);
		}

		override flash_proxy function hasProperty(name: *): Boolean
		{
			// A property exists if it's inside the managedObj or the dynamicObj
			return (_managedObjProxy.hasOwnProperty(name) ||
				_dynamicObjProxy.hasOwnProperty(name));
		}

		override flash_proxy function nextName(index: int): String
		{
			return _propertyList[index - 1];
		}

		override flash_proxy function nextNameIndex(index: int): int
		{
			if (index == 0)
			{
				// I update the list of alla the properties available in the proxy,
				// those from the managedObj and those dynamically created in the
				// dynamicObj.
				updatePropertyList();
			}

			if (index < _propertyList.length)
			{
				return index + 1;
			}
			else
			{
				return 0;
			}
		}

		override flash_proxy function nextValue(index: int): *
		{
			return flash_proxy::getProperty(_propertyList[index - 1]);
		}

		override flash_proxy function setProperty(name: *, value: *): void
		{
			// If the property is in the managedObj then I set its value, otherwise
			// I set the value on the dynamicObj (the property is created if it
			// doesn't already exist).
			if (_managedObjProxy.hasOwnProperty(name))
			{
				_managedObjProxy[name] = value;
			}
			else
			{
				_dynamicObjProxy[name] = value;
			}
		}

		// *** IEventDispatcher implementation ***

		public function addEventListener(type: String, listener: Function,
			useCapture: Boolean = false, priority: int = 0,
			useWeakReference: Boolean = false): void
		{
			_dispatcher.addEventListener(type, listener, useCapture, priority,
				useWeakReference);
		}

		public function removeEventListener(type: String, listener: Function,
			useCapture: Boolean = false): void
		{
			_dispatcher.removeEventListener(type, listener, useCapture);
		}

		public function dispatchEvent(event: Event): Boolean
		{
			return _dispatcher.dispatchEvent(event);
		}

		public function hasEventListener(type: String): Boolean
		{
			return _dispatcher.hasEventListener(type);
		}

		public function willTrigger(type: String): Boolean
		{
			return _dispatcher.willTrigger(type);
		}
	}
}

package com.devahead.model
{
	[Bindable]
	public class Fruit
	{
		public var name: String;
		public var quantity: int;

		public function Fruit(name: String, quantity: int = 0)
		{
			this.name = name;
			this.quantity = quantity;
		}
	}
}

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
	pageTitle="Dynamic ObjectProxy - devahead BLOG"
	layout="vertical" horizontalAlign="left"
	applicationComplete="{onApplicationComplete(event)}"
	viewSourceURL="srcview/index.html">

	<mx:Script>
		<![CDATA[
			import com.devahead.utils.DynaObjectProxy;
			import com.devahead.model.Fruit;
			import mx.collections.ArrayCollection;
			import mx.events.FlexEvent;

			[Bindable]
			protected var fruitsList: ArrayCollection = new ArrayCollection();

			protected function onApplicationComplete(event: FlexEvent): void
			{
				// Wrap the Fruit instances in DynaObjectProxy instances
				// so we can add the "isFruitSelected" property dynamically
				// in the grid.
				fruitsList.addItem(new DynaObjectProxy(new Fruit("Orange")));
				fruitsList.addItem(new DynaObjectProxy(new Fruit("Pear")));
				fruitsList.addItem(new DynaObjectProxy(new Fruit("Apricot")));
			}

			protected function getSelectedFruits(): void
			{
				selFruitsArea.text = "SELECTED FRUITS:\n\n";

				var originalFruitsInstances: ArrayCollection = new ArrayCollection();

				for each (var currFruit: DynaObjectProxy in fruitsList)
				{
					// If the fruit is selected, I add it to the selFruitsArea
					if (currFruit.isFruitSelected)
					{
						selFruitsArea.text += currFruit.name + " (" +
							currFruit.quantity + ")\n";

						// Get the instance of the Fruit class managed by the
						// DynaObjectProxy.
						originalFruitsInstances.addItem(currFruit.managedObj);
					}
				}

				selFruitsArea.text += "\nORIGINAL INSTANCES OF SELECTED FRUITS:\n\n";

				for each (var currOriFruit: Fruit in originalFruitsInstances)
				{
					selFruitsArea.text += currOriFruit.name + " (" +
						currOriFruit.quantity + ")\n";
				}
			}
		]]>
	</mx:Script>

	<mx:Label text="Select some fruits, edit their quantity, and press the 'Get selected fruits' button"
		fontWeight="bold"/>

	<mx:DataGrid width="300" height="100" dataProvider="{fruitsList}"
		editable="true">
		<mx:columns>
			<mx:DataGridColumn headerText="Selected" dataField="isFruitSelected"
				rendererIsEditor="true" itemRenderer="mx.controls.CheckBox"
				editorDataField="selected" textAlign="center"/>
			<mx:DataGridColumn headerText="Name" dataField="name" editable="false"/>
			<mx:DataGridColumn headerText="Quantity" dataField="quantity"/>
		</mx:columns>
	</mx:DataGrid>

	<mx:TextArea id="selFruitsArea" width="300" height="200"/>

	<mx:Button label="Get selected fruits" click="{getSelectedFruits()}"/>
</mx:Application>